label level03:
    
    scene bg black with dissolve
    pause (0.3)
    scene bg inn hallway night with dissolve
    
    tisha serious "Where's Katya?  Has anyone seen her?"
    
    show sadie serious at mid_left with fast_dissolve
    sadie "I think she went up to the tower.  She said she was going to get things set up, right?"
    
    tisha suspicious "The tower..."
    
    show rosemarie worried at mid_right with fast_dissolve
    rosemarie "That does make sense.  I mean, if she set up a bunch of pranks all over the hotel, the biggest prank is probably up in the tower.  That's why she must have wanted us to get there?  Right?"
    
    show sadie scoff at mid_left with fast_dissolve
    sadie "Only Katya could find a real haunted mansion."
    
    hide rosemarie
    
    show mika frown at mid_right with fast_dissolve
    mika "It's not ghosts."
    
    show sadie annoyed at mid_left with fast_dissolve
    sadie "It sure seems like ghosts to me!"
    
    show mika glare at mid_right with fast_dissolve
    mika "I know my ghosts.  This isn't them."
    
    tisha serious "Let's just go up to the tower and get Katya. We can solve this mystery later."
    
    scene bg black with dissolve
    pause (0.3)
    scene bg inn hallway night with dissolve
    
    "The door knob still won't move no matter how much I jiggle it."
    
    tisha serious "The door's locked."
    
    show elise uncertain at mid_left with fast_dissolve
    elise  "Do you think there's a key around here?  It's a puzzle like in a video game.  I think..."
    
    hide elise with dissolve
    
    spirit "WHAT IS LOST CAN NEVER BE FOUND.  WHAT IS LOST CAN NEVER BE FOUND."
    "A booming voice announces as a dark shape coalesces at the end of the hall."
    
    spirit "WHAT IS LOST CAN NEVER BE FOUND."
    
    "The shape is larger than a human, both in size and height, and far more solid looking than the other shadows occupying the inn.  It's eyes glow with a malicious light."
    
    show elise startled at mid_left with dissolve
    elise "What is that?!"
    
    show sadie serious at mid_right with dissolve
    sadie "I don't know, but Katya is on the other side of that door.  And it's stopping us from reaching her!"
    show sadie annoyed at mid_right with fast_dissolve 
    sadie "I'll force it to let us in!"
    
    tisha startled "Sadie, no!  You can't cast a spell in anger.  That's the first rule of witch craft!"
    
    show rosemarie awkward_smile with dissolve
    rosemarie "Maybe, um, maybe we can talk to it?  I mean, isn't that, um, there's always more than one way to scramble an omelette? ..aheheh."
    

    spirit "LEAVE THIS PLACE!"
    
    show sadie serious at mid_right with fast_dissolve
    sadie "No.  Give us our friend back!"
    
    spirit "THIS IS YOUR PENALTY."
    "The dark shape grows in size, it's outline wavering wildly."
    
    show sadie annoyed at mid_right with fast_dissolve
    sadie "Penalty?  Penalty?!  For what?  We haven't done anything!!"
    "Sadie looks like she'd like to go punch the strange shape."
    
    spirit "ALL HUMANS ARE GUILTY."
    
    show elise serious at mid_left with fast_dissolve
    elise "If you tell us what happened, maybe we can help.  We're witches after all, that's what we do.  Help."
    
    hide elise
    hide sadie
    hide rosemarie
    with nice_wiperight
    
    pause (0.3)
    scene bg black with slow_dissolve
    pause (0.3)
    scene bg inn evening with slow_dissolve
    
    "HUMANS CAME."
    
    "In my mind, I see two men in suits enter the dilipidated inn."
    
    "THEY COULD NOT SEE US."
    
    "AND THEY TRAPPED MY SISTER BEYOND MY REACH."
    
    scene bg black with dissolve
    pause (0.3)
    scene bg inn hallway night with dissolve
    
    spirit "THE HUMANS TOOK SOMETHING OF MINE SO I WILL TAKE SOMETHING THAT BELONGS TO THE HUMANS."
    
    show elise serious at mid_left with dissolve
    elise "But.... But...."
    
    tisha curious "What if we make a trade?"
    
    spirit  "TRADE?  I WILL NOT MAKE A TRADE."
    
    tisha sad_smile "We can find your sister and free her from wherever she's trapped.  Then can we have our friend back?"
    
    "The hulking shadowy shape at the end of the hall is silent for a  moment before answering."
    
    spirit "ACCEPTED."
    
    show sadie annoyed at mid_right with dissolve
    sadie "So where is your sister?"
    
    "The shadow growls, a deep menacing sound."
    
    tisha serious "(Maybe it can't say... Or maybe this is a test... )"
    
    "There are lots of places we can look in the inn, where should I even start looking?"
    
    ## For anyone who might have save data from the demo
    ## This will keep the game from crashing when it tries to read the menu below
    $ seen_ballroom_level03 = False
    $ seen_courtyard_level03 = False
    $ seen_NW_Room_level03 = False
    $ seen_NE_Room_level03 = False
    $ seen_SE_Room_level03 = False
    
label menu_level03:
    
    menu:
        "I'll check..."
        "The Ballroom" if seen_ballroom_level02 and not seen_ballroom_level03:
            jump ballroom_level03
        "The Courtyard" if seen_courtyard_level02 and not seen_courtyard_level03:
            jump courtyard_level03
        "The Room with All the Eyes" if seen_NW_Room_level02 and not seen_NW_Room_level03:
            jump NW_Room_level03
        "The Room with the Oooh-ing Shape" if seen_NE_Room_level02 and not seen_NE_Room_level03:
            jump NE_Room_level03
        "The Room with the Grandfather Clock":
            jump happy_ending
        "The Room with the Fake Corpse" if seen_SE_Room_level02 and not seen_SE_Room_level03:
            jump SE_Room_level03
        
        
label ballroom_level03:
    
    scene bg black with dissolve
    pause (0.3)
    scene bg ballroom night with dissolve
    
    "The pale specters drift around the ceiling, watching us as we spread out to find any sign of where the shadow's sister might be captured."
    "Our search turns up nothing."
    
    $ seen_ballroom_level03 = True
    
    jump menu_level03
    
label courtyard_level03:
    
    scene bg black with dissolve
    pause (0.3)
    scene bg inn lobby night with dissolve
    
    "The door to the courtyard is still locked when I go outside to check on it."
    "A voice cries outside."
    
    show rosemarie uncertain at mid_left with dissolve
    rosemarie "Are- are you okay?"
    
    "The crying continues without pause."
    
    tisha serious "It's been like that for a while."
    
    show rosemarie worried at mid_left with fast_dissolve
    rosemarie "I wish we could help her."
    
    show mika glare at mid_right with dissolve
    mika "How do we know that isn't the whatever-is-upstair's sister?"
    
    tisha curious "The door was open earlier.  I don't think it's locked out there, I just think it's trying to keep us out."
    
    show rosemarie uncertain at mid_left with fast_dissolve
    rosemarie "We wouldn't hurt it. I promise!"
    
    tisha serious "I don't think the shadow's sister is here after all...."
    
    $ courtyard_level03 = True
    
    jump menu_level03
    
label NW_Room_level03:
    
    scene bg black with dissolve
    pause (0.3)
    scene bg inn rooms night with dissolve
    
    "The writhing shape with the eyes has grown since it had Mika trapped in here."
    "We stay far away from that corner of the room, but find nothing that seems to be the shadow's sister."
    
    $ seen_NW_Room_level03 = True
    
    jump menu_level03
    
label NE_Room_level03:
    
    scene bg black with dissolve
    pause (0.3)
    scene bg inn rooms night with dissolve
    
    spirit "Oooohhh..... Oooohhhhh...."
    "The pale shape on the bed shivers when we come into the room."
    
    show elise serious at mid_right with dissolve
    elise "Don't be scared."
    
    spirit "Oooohhh....  Oooohhhh...."
    
    "Other than moaning, the pale shape makes no move to interfere with our search."
    "This room contains no clues."
    
    $ seen_NE_Room_level03 = True
    
    jump menu_level03
    
label SE_Room_level03:
    
    scene bg black with dissolve
    pause (0.3)
    scene bg inn rooms night with dissolve
    
    "Somehow, the corpse has diappeared."
    "Still, the room does not contain any clues to where the shadow's sister might be."
    
    $ seen_SE_Room_level03 = True 
    
    jump menu_level03
    