label intro_001:
    
    scene bg night sky with dissolve
    
    "From this distance, the town looks like a string of low, glittering stars nestled between sea and sky."
    "Real stars speckle the sky overhead with the moon hangs bright and low overhead.  It's a good night for witch craft."
    
    scene bg black with nice_wipedown
    pause (0.3)
    scene bg beach path night with dissolve
    
    "I let out a soft, low sigh, feeling a pang in my heart.  This is my last full moon on the island -- in two weeks, I'll be done packing and I'll be on my way to my new dorm room at university."
    tisha serious "(No, I told myself I wasn't going to feel sad tonight.)"
    
    show rosemarie awkward with dissolve
    rosemarie "Oh, ah, Tish!  What, um, what lovely weather we're having!  Well, actually, the weather has been a bit miserably hot, wouldn't you say? ...a heh heh."
    
    tisha curious "Am I the last one here again?"
    
    show rosemarie startled with fast_dissolve
    rosemarie "Oh no!  You're not!"
    show rosemarie awkward_smile with fast_dissolve
    rosemarie "Well, actually... You are the last one here.  But it isn't a big deal! In fact, I mean, well, don't worry about it."
    "Rosemarie is even more awkward than usual tonight.  I pat her shoulder."
    
    tisha smile "The breeze off the water is cooling the night off.  We'll have a good flight tonight."
    
    show rosemarie startled with fast_dissolve
    rosemarie "Oh no!  You can't- you can't go to the beach yet!"
    "Rosemarie waves her arms frantically to block my progress to the beach."
    
    tisha suspicious "What?  Why?"
    
    show rosemarie awkward_smile with fast_dissolve
    rosemarie "No reason!  No reason at all ...a heh heh heh!"
    "Now I know she's hiding something."
    
    tisha very_suspicious "Hmm..."
    
    show rosemarie startled with fast_dissolve
    rosemarie "What's that face for?  What's that face for??"
    
    show rosemarie awkward with fast_dissolve
    rosemarie "I'm not stalling or anything, I promise!"
    
    tisha smile "Well, I've been stalled. Come on, let's go meet up with everyone else."
    "I pat Rosemarie on the shoulder again and walk around her to continue down the path."
    
    show rosemarie disappointed with fast_dissolve
    rosemarie "Tisha...  You're not supposed to go to the beach yet...!"
    
    hide rosemarie with dissolve
    
    scene bg black with dissolve
    pause (0.3)
    scene bg beach night with dissolve
    
    "As soon as I clear the grasses and step out onto the beach, the other girls immediately stop talking and look up from their cluster near the driftwood that lines the beach."
    "It's exactly the way people will stop talking if you walk into the room  while they are talking about you."
    
    tisha very_suspicious "(Now I know they're up to something.)"
    
    "I face the other five girls in the Admiralo Island Witches Club."

    show mika frown with nice_wipeup
    "Mika Nakamura."
    hide mika with nice_wipedown

    show elise smile with nice_wipeup
    "Elise Sandoval."
    hide elise with nice_wipedown

    show sadie smile with nice_wipeup
    "Sadie Bridger."
    hide sadie with nice_wipedown

    show katya smile with nice_wipeup
    "Katya Morosov."
    hide katya with nice_wipedown

    show rosemarie smile with nice_wipeup
    "And Rosemarie Abernathy."
    hide rosemarie with nice_wipedown

    "The way Rosemarie had been carrying on, I'd been expecting a big surprise party or something."
    tisha sad_smile "(I said I didn't want a going away party, but...)"
    "I have to admit a tiny part of me feels disappointed that there isn't even a cake."

    tisha curious "What are you guys up to?"

    show katya big_smile at mid_left with dissolve
    katya "Oh.  Nothing, nothing at all."
    
    tisha suspicious "Oh really?"
    
    "If Katya says that she isn't plotting then that's the most suspicious thing of all."
    
    show katya smile at mid_left with fast_dissolve
    katya "Relax, boss.  You worry too much."
    
    show sadie smile at mid_right with dissolve
    sadie "Yeah!  You worry far, far too much."
    
    "Out of the corner of my eye, I see Sadie make a motion with her hand."

    hide katya
    hide sadie
    with dissolve

    show elise startled with dissolve
    elise  "Oh!"
    show elise uncertain with fast_dissolve
    elise "We're not up to anything.  Anything at all."
    "Elise states in a strangely flat voice."
    show elise smile with fast_dissolve
    elise "I think..."
    hide elise with dissolve
    "And Elise buries her face in her hands and runs a few feet down the beach to hide her embarassment."

    show mika glare with dissolve
    mika "Good job, guys."
    hide mika with dissolve
    "Mika glares at Katya and Sadie before dashing down the beach to catch up to Elise."

    "After a bit of coaxing, Elise returns to the group."

    tisha smile "So shall we start our final full moon flight of the summer?"
    show sadie grin with dissolve
    sadie "Let's get this party started.  I got dressed up special just for this."
    "Sadie picks up her broom from where she'd propped it against some driftwood and poses with it as if someone were nearby to take her photo."
    hide sadie with dissolve
    "The other girls murmur their assent and any previous differences are forgotten."

    scene bg black with nice_wipeup
    pause (0.3)
    scene bg sky night with dissolve
    pause (0.5)
    scene bg black with dissolve
    pause (0.3)
    scene bg beach night with nice_wipedown

    "A cool, refreshing breeze blows in off the sea as the six of stand in a circle."
    "I look around the circle, feeling my heart swell with emotion."
    "I'm going to miss this.  The club, the island and especially my friends."
    show elise uncertain at mid_right with dissolve
    elise "You ready, Tisha?"
    "Elise asks quietly."
    hide elise with dissolve
    "Everyone is looking at me, waiting for me to start the spell."
    "My final duty as the president of the Witches Club before I retire."

    "I clear my throat."
    "Slowly, I reach out my right hand and speak the name of a single rune.  It flares to life, floating like a luminescent shape over my outstretched palm."
    "The other girls each add their own rune to the spell until the six of us have each contributed a single rune."
    "For a brief moment, the six runes burn brightly then -- "

    scene bg beach night with flash

    extend "with a flash the runes disappear."
    "At the same time, our brooms lift skyward."

    show katya big_smile at mid_left with dissolve
    katya "I'll race you, Sadie!"
    hide katya with nice_wipeleft
    "Katya hops on her broom and zips away over the water."
    show sadie annoyed at mid_right with dissolve
    sadie "Hey, wait up!!"
    hide sadie with nice_wiperight
    "Sadie shouts after the shrinking form of Katya before she hops on her own broom."

    show mika frown with dissolve
    mika "...."
    hide mika with nice_wipeup
    "Without saying anything, Mika kicks off from the ground and flies off in the opposite direction of the other two."

    show rosemarie smile at mid_left with dissolve
    elise "Oh, oh my!  My seagull friends are here!  Here!  We should fly together, right?"
    hide rosemarie with slow_nice_wipeup
    "Rosemarie pushes herself up from the sand and glides behind a group of seagulls."

    show elise uncertain at mid_right with dissolve
    elise "We got left behind again.  Come on, Tisha!"
    hide elise with nice_wipeup

    scene bg black with nice_wipeleft
    pause (0.3)
    scene bg sky night with nice_wipeleft
    
    "Like a sea bird, I cut through the breeze, feeling the rush and exhiliration of freedom that flying brings."
    "I dip low over the water and the spray of the waves touches the hem of my dress.  Leaning over, I let my fingers trail in the water."
    "The moon sails across the sky, watching over us we soar and dive and laugh."
    
    scene bg black with nice_wipedown
    pause (0.3)
    scene bg beach night with dissolve
    
    "One by one, we touch down on the beach as the spell begins to fade and our brooms begin to drag."
    "For a while, I stand at the edge of the water watching the light of the moon as it shimmers in the its reflection in the water."
    "Sand shifts in and out of my sandals with the waves."
    
    show mika serious at mid_left with dissolve
    mika "I told my mom I wouldn't stay out too late."
    "Mika is the first one to break the quiet."
    
    tisha curious "Do you need a ride?"
    
    show mika reluctant at mid_left with fast_dissolve
    mika "Yeah, sure.  If it's not a big deal."
    
    tisha smile "No deal at all."
    
    hide mika with dissolve
    
    "As if another spell had ended, the six of us turn back from the water and begin the trek out to the parking lot."
    
    scene bg black with dissolve
    pause (0.3)
    scene bg beach path night with dissolve
    
    show katya thoughtful with dissolve
    katya "You know, it's a shame that summer's almost over and we haven't had a single adventure yet."
    "Katya carries her broom easily, slung over her shoulder."
    
    show elise uncertain at mid_right with dissolve
    elise "Isn't it a good thing that it's been a quiet summer?"
    
    show katya annoyed with fast_dissolve
    katya "Sure!  But it's boring.  I want to have daring-dos and swashbuckles!"
    
    show mika frown at mid_left with fast_dissolve
    mika "That's not the way the world works.  Adventures aren't usually fun while you're having them.  It's more like 'my car broke down and now I have to walk back into town'."
    
    hide elise with dissolve
    
    show rosemarie awkward_smile at mid_right with dissolve
    rosemarie "Why didn't you just call someone on your cell phone?  Someone could have picked you up."
    
    show mika glare at mid_left with fast_dissolve
    mika "That's not--  It was more of a hypothetical inconvenience."
    
    show katya big_smile with fast_dissolve
    katya "I mean a real adventure,  not just your car breaking down."
    
    hide mika with dissolve
    
    show sadie scoff at mid_left with fast_dissolve
    sadie "Give it up, Katya.  Not even you can make an adventure happen if it doesn't want to happen.  You have to discover one of those naturally."
    
    show katya annoyed with fast_dissolve
    katya "Is that a challenge?"
    
    tisha groan "Oh no.... Katya, that was not a challenge.  Just a statement."
    
    show katya thoughtful with fast_dissolve
    katya "I wonder if I could..."
    "Katya's voice drops low as she loses herself in thought and wanders ahead of us up the path."
    
    hide katya with dissolve
    
    show rosemarie worried at mid_right with fast_dissolve
    rosemarie "An adventure wouldn't be so bad, would it?"
    
    show sadie annoyed at mid_left with fast_dissolve
    sadie "Relax.  I'm sure Katya will forget about it in the morning."
    
    hide sadie
    hide rosemarie
    with dissolve
    
    "Abruptly, we find ourselves at the edge of the path where it meets up with the parking lot for the beach."
    "The Witches Club has special permission to use the park after dark and our cars are the only ones in the lot."
    "We stand at the edge of the lot, afraid to cross over and end the evening."
    
    
    show elise uncertain at mid_right with dissolve
    elise "It's not going to be the same without you."
    "Elise comments so quietly I can barely hear her."
    
    show sadie annoyed at mid_left with dissolve
    sadie "Ssh!"
    "Sadie raises a hand to shush her friend."
    show sadie serious at mid_left with fast_dissolve
    sadie "We promised we wouldn't talk about sad stuff tonight."
    
    show elise serious at mid_right with fast_dissolve
    elise "I know, but..."
    
    tisha serious "Oh, guys...  Come here."
    "I gesture the others closer and as soon as Elise and Sadie come within range, I hug both of them tightly."
    tisha sad_smile "I'll miss you too."
    
    hide sadie
    hide elise
    with dissolve
    
    "Katya, Rosemarie and even Mika step closer to join in a big group embrace."
    "And we stand as one in the night."
    
    scene bg black with dissolve
    pause (0.3)
    scene bg sky night with nice_wipeup
    pause (0.5)
    scene bg sky day with slow_dissolve
    
    "The sound of a flurry of texts wakes me the following day."
    "I rub the sleep from my eyes and check the time.  It's after noon."
    tisha serious "(I guess it's time to get up...)"
    "Still groggy, I unlock my phone and check my texts."
    
    "{b}Katya{/b} Foxglove Hill Inn.  Tonight.  Sunset.  Be there!"
    "{b}Sadie{/b}  If this is some kind of practical joke I will kill you KATYA"
    "{b}Katya{/b}  Just wait and see."
    "{b}Mika{/b} That sounds ominous."
    "{b}Sadie{/b} I'll kill you I promise"
    "{b}Rosemarie{/b} Is that the abandoned inn on the bluff?"
    "{b}Rosemarie{/b}  It always seems so sad to me :( "
    "{b}Sadie{/b}  Shes plotting something!!!!!"
    "{b}Elise{/b} I'll be there I love that old hotel"
    
    "Smiling, I text back to say that I'll be there as well."
    
    scene bg sky evening with slow_dissolve
    pause (0.5)
    scene bg black with nice_wipedown
    pause (0.3)
    scene bg inn evening with dissolve
    
    show katya big_smile with dissolve
    katya "You guys are late!"
    
    show elise uncertain at mid_right with dissolve
    elise "I looked online, sunset isn't for another fifteen minutes.  I think..."
    
    show katya thoughtful with fast_dissolve
    katya "Whatever. If I am here first, then everyone else is late."
    
    show mika glare at mid_left with dissolve
    mika "Let's just get this over with.  What kind of crazy scheme did you come up with this time?"
    
    show katya smile with fast_dissolve
    katya "It's not a crazy scheme. It's an adventure!"
    
    hide elise with dissolve
    
    show sadie annoyed at mid_right with dissolve
    sadie  "See?  I told you it was a trick."
    
    show katya serious with fast_dissolve
    katya "It's not a trick either.  It's a test of courage.  I spent all day on it.  Please, guys, please?"
    
    tisha curious "So what's involved with test of courage?"
    
    show katya big_smile with fast_dissolve
    katya "See?  That's the ol' boss for you."
    "She points out the tower that juts out from the Victorian style building."
    show katya serious with fast_dissolve
    katya " All you have to do is make it to the top of the tower!  I put a book up there and you sign your name it.  Thus proving your bravery."
    
    show sadie serious at mid_right with fast_dissolve
    sadie "That sounds surprisingly sensible for you."
    
    show katya fake_sigh with fast_dissolve
    katya "Always the doubter, aren't you, Sadie?"
    
    show sadie scoff at mid_right with fast_dissolve
    sadie "I don't doubt everything, I just doubt your ability to act sensibly."
    
    show katya big_smile with fast_dissolve
    katya "Thanks!"
    
    hide mika with dissolve
    
    show rosemarie awkward at mid_left with dissolve
    rosemarie "Oh, um, isn't it usually more traditional to light a candle during a test of courage?  I saw it in a comic once."
    
    show katya thoughtful with fast_dissolve
    katya "I wanted to have it so you would light a candle, but then I got a little worried that we'd burn the place down somehow."
    
    hide rosemarie with dissolve
    
    show elise serious at mid_left with dissolve
    elise "Um...  Aren't we ignoring the most basic problems with this adventure?  Isn't this building private property?  I think..."
    
    show katya smile with fast_dissolve
    katya "Oh, don't worry about that.  I've been stomping around inside all day and no one stopped me."
    
    show elise uncertain at mid_left with fast_dissolve
    elise "But won't we be trespassing and that's againg the law?  I think..."
    
    show sadie serious at mid_right with fast_dissolve
    sadie "You're such a good kid."
    "Sadie sounds impressed as she speaks."
    
    show elise serious at mid_left with fast_dissolve
    elise "... And anyway, isn't this where Marta was supposed to have died?"
    
    hide sadie with dissolve
    
    show rosemarie awkward_smile at mid_right with fast_dissolve
    rosemarie "Who's Marta?"
    "Rosemarie asks, showing that she's only moved to the island recently."
    
    show elise lecture at mid_left with fast_dissolve
    elise "Well.  Marta was a witch who lived on Admiralo Island many years ago and--"
    
    tisha groan "(Oh no... She's gone into lecture mode.)"
    
    show katya big_smile with fast_dissolve
    katya "And she died under mysterious circumstances.  Blah blah blah.  This was all back in the granny days."
    
    show elise serious at mid_left with fast_dissolve
    elise "The inn is supposed to be haunted!  That's why it's been for sale this long! It's Marta's ghost."
    
    show katya smile with fast_dissolve
    katya "And what would a test of courage be without a little haunting?  So what do you guys say, are you in?  One last adventure for the summer?"
    
    "The others glance at each other uncertainly.  No one wants to be the first to say anything."
    
    tisha serious "I'm in."
    
    show rosemarie awkward at mid_right with fast_dissolve
    rosemarie "If Tish is in, then I'm in."
    
    hide rosemarie
    hide katya
    hide elise
    with dissolve
    
    pause (0.5)
    
    scene bg inn night with super_slow_dissolve
    
    "And so we decide that we would participate in Katya's test of courage."
    "Katya dashes off ahead to 'get things ready' (whatever that means), leaving us only with the instructions that we should enter one by one once the sun sets."
    "We draw straws to choose our entry order."
    
    tisha serious "(Somehow I got last.)"
    
    "So I wait outside inn as each of the other girls enters on her own, five minutes apart."
    
    tisha curious "(I guess it's my turn now.)"
    
    scene bg black with dissolve
    pause (0.3)
    
    jump lobby_level01
    
label happy_ending:
    
    scene bg black with dissolve
    pause (0.3)
    scene bg inn rooms night with dissolve
    
    "The glass door set in the trunk of the grandfather clock glows slightly, but immediately dims as soon as we enter the room."
    
    show sadie scoff at mid_right with dissolve
    sadie "Not this place again."
    
    show rosemarie awkward_smile at mid_left with dissolve
    rosemarie "Guys?  Guys.  I think there's something in the clock."
    "Rosemarie leans close and stares into the column of the clock."
    
    show sadie annoyed at mid_right with fast_dissolve
    sadie "Be careful.  That thing tried to hypnotize me before."
    "Sadie takes Rosemarie's arm and pulls her away before she can stare too long."
    
    show rosemarie startled at mid_left with fast_dissolve
    rosemarie "I saw, I saw eyes inside the clock!"
    
    show mika frown with dissolve 
    mika "It makes sense.  The case is locked with metal."
    "Mika points at the decorative work around the edges of the column and the lock itself."
    show mika serious with fast_dissolve
    mika "Probably couldn't get in."
    
    show rosemarie uncertain at mid_left with fast_dissolve
    rosemarie "Well, what if-- No, it's locked..."
    "Rosemarie struggles with the latch to the case of the grandfather clock."
    
    show sadie grin at mid_right with fast_dissolve
    sadie "Let me try."
    "Sadie pretends to spit into her hands."
    show sadie serious at mid_right with fast_dissolve
    sadie "I'm tougher than I look."
    
    hide mika
    hide sadie
    hide rosemarie
    with nice_wipeleft
    
    show elise uncertain at mid_left with nice_wiperight
    elise "Um... um...."
    
    hide elise with nice_wiperight
    
    show sadie serious at mid_right
    show rosemarie uncertain at mid_left
    show mika frown
    with nice_wipeleft
    
    show sadie scoff at mid_right with fast_dissolve
    sadie "This is more difficult than I thought it would be."
    
    show mika glare with fast_dissolve
    mika "What?  You barely tried."
    
    show sadie annoyed at mid_right with fast_dissolve
    sadie "You try it then."
    
    show mika serious with fast_dissolve
    mika "Fine."
    
    hide mika
    hide sadie
    hide rosemarie
    with nice_wipeleft
    
    show elise lecture at mid_left with nice_wiperight
    elise "Everyone!!"
    
    "Elise shouts."
    "The bickering between Sadie and Mika ceases as they turn to stare at Elise."
    
    show elise startled at mid_left with fast_dissolve
    pause (0.3)
    show elise serious at mid_left with fast_dissolve
    elise "We're witches.  We can open the lock with magic."
    "Elise fidgets with everyone's eyes on her."
    show elise uncertain at mid_left with fast_dissolve
    elise "Would someone mind casting the open spell with me?"
    
    
    show rosemarie awkward_smile at mid_right with fast_dissolve
    rosemarie "Oh, I'll do it, I'll do it!  I mean, if that's okay and no one minds."
    
    hide elise
    hide rosemarie
    with dissolve
    
    scene bg inn rooms night with flash
    "Both Elise and Rosemarie speak one half of the opening spell and, with a click, the door into the column of the grandfather clock swings open."
    "Almost immediately, a softly glowing greenish-gold orb jumps out of the clock.  It hovers in the center of us, dark colored eyes taking in each of us in turn."
    
    spirit "Are you witches?"
    
    tisha smile "We are."
    
    spirit "My thanks to you, witches.  I have been locked inside that prison for weeks now."
    
    show sadie annoyed at mid_right with dissolve
    sadie "So what happened?"
    
    spirit "Those human men could not see me.  They did not know that they had shut me inside."
    
    show sadie scoff at mid_right with fast_dissolve
    sadie "Figures."
    
    spirit "And now I must go and see my sisters.  I am sorry for any trouble the oldest may have caused you."
    
    "The little orb of light dimmed slightly before zipping out of the room."
    
    show rosemarie awkward_smile at mid_left with dissolve
    rosemarie "She, um, she seemed nice."
    
    show mika serious with dissolve
    mika "Yeah, for someone holding our friend hostage."
    
    show rosemarie awkward at mid_left with fast_dissolve
    rosemarie "Y-yeah, but we saved her and now everyone is happy.  And everything is good, right?  Right?"
    
    show sadie annoyed at mid_right with fast_dissolve
    sadie "Guys!"
    show sadie grin at mid_right with fast_dissolve
    sadie "Let's go see Katya!"
    
    hide sadie
    hide rosemarie
    hide mika
    with dissolve
    
    scene bg black with dissolve
    pause (0.3)
    scene bg white with dissolve
    pause (0.3)
    scene bg inn tower night with dissolve
    
    show katya big_smile with nice_wipeup
    katya "Surprise!"
    show katya annoyed with fast_dissolve
    katya "Hey, I thought I told you guys to walk up separately!  I didn't spend all that time setting those traps-- er, surprises for nothing!"
    
    show rosemarie worried at mid_right with dissolve
    rosemarie "Katya!  You're okay!"
    
    hide rosemarie with nice_wipeleft
    
    "Rosemarie races across the room and throws her arms around Katya in a giant hug."
    "Seconds later, the rest of us follow suit."
    
    show katya smile with fast_dissolve
    katya "What's all this for?"
    
    show elise lecture at mid_left with dissolve
    elise "Well, you see..."
    
    hide katya
    hide elise
    with dissolve
    
    scene bg black with dissolve
    pause (0.3)
    scene bg inn tower night with dissolve
    
    show katya annoyed with dissolve
    katya "I missed the adventure!  I can't believe it!"
    
    show sadie scoff at mid_right with dissolve
    sadie "Well, well.  With all your plotting and you turned into the princess in the tower, Katya."
    
    show katya serious with fast_dissolve
    katya "Me?  A princess?"
    show katya annoyed with fast_dissolve
    katya "Take that back!"
    
    hide katya
    hide sadie
    with nice_wipeleft
    
    "Katya chases Sadie across the room, their feet thumping loudly agains the floor."
    
    tisha curious "What's all this on the table for, Katya?"
    
    "Katya halts in her tracks."
    
    show katya big_smile at mid_left with fast_dissolve
    katya "Oh!  This is your going away party, Tish."
    show katya serious at mid_left with fast_dissolve
    katya "I know you said you didn't want a party, but um..."
    show katya smile at mid_left with fast_dissolve
    katya "I did it anyway.  Sorry!"
    
    hide katya with dissolve
    
    "I look around at the cake, the streamers and the lights.  Not only had Katya set up all the tricks downstairs, but also decorated the tower room."
    
    show elise uncertain at mid_right with fast_dissolve
    elise "Katya, did you make this?"
    "Elise indicates the cake on the table."
    
    show katya big_smile at mid_left with fast_dissolve
    katya "Tch.  You know me.  I can't cook.  My mom made it."
    
    show sadie scoff with dissolve
    sadie "Aren't you forgetting something, Katya?"
    
    show katya smile at mid_left with fast_dissolve
    katya "Forgetting what?"
    
    show sadie annoyed with fast_dissolve
    sadie "The thing!"
    
    hide elise with dissolve
    
    show rosemarie awkward at mid_right with fast_dissolve
    rosemarie "Oh, you two.  Quite squabbling right now.  Please?"
    
    show sadie scoff with fast_dissolve
    sadie "Fine, fine..."
    
    show rosemarie smile at mid_right with fast_dissolve
    rosemarie "I have the thing anyway."
    
    tisha curious "What thing?"
    
    hide sadie
    hide rosemarie
    hide katya
    with dissolve
    
    show elise smile with dissolve
    elise "We decided, well, it was Katya's idea really--"
    
    show katya smile at mid_right with fast_dissolve
    katya "Right, it was my idea!"
    
    show elise uncertain with fast_dissolve
    elise "We decided to make you something.  In fact, we just finished it up last night."
    
    tisha smile "So that's what you were up to when I arrived at the beach."
    
    show elise serious with fast_dissolve
    elise "Yeah."
    
    hide elise
    hide katya
    with dissolve
    
    show rosemarie smile with dissolve
    rosemarie "So here it is, our present to you.  From everyone at the Admiralo Island Witches Club."
    "Rosemarie retrieves a small box from within her shawl and holds it out to me."
    show rosemarie awkward_smile with fast_dissolve
    rosemarie "So, um, this is from all of us.  Thank you for being so nice to me when I was new to the, um, the island."
    hide rosemarie with dissolve
    
    show katya big_smile with dissolve
    katya "Yeah, don't forget about us when you're out there in the big world.  Not that you could forget about someone like me."
    hide katya with dissolve
    
    show sadie grin with dissolve
    sadie "We hope you have a really good time at college and learn lots of neat stuff!"
    hide sadie with dissolve
    
    show mika frown with dissolve
    mika "I'm sure you'll be fine."
    hide mika with dissolve
    
    show elise serious with dissolve
    elise "I'm going to miss you."
    "Elise wipes her eyes with the back of her hand."
    
    show katya smile at mid_right with fast_dissolve 
    katya "Hey, none of that sad stuff."
    "Katya hands a cup of sparkling beverage to Elise."
    
    hide elise
    hide katya
    with dissolve
    
    tisha sad_smile "Thank you, everyone.  I  mean it."
    "Slowly and carefully, I remove the wrapping from the tiny package and open up the box inside."
    "A small pendant, about the size of quarter, rests inside.  The surface is a dark blue color with tiny specks that sparkle like stars."
    tisha smile "It's beautiful, thank you!"
    
    show rosemarie smile at mid_left with fast_dissolve
    rosemarie "That's not the best part.  Hold it up to your ear, like-like this!"
    "Rosemarie mimics cupping her hands to her ear."
    
    "I copy Rosemarie."
    tisha startled "It's the ocean!"
    
    show sadie scoff at mid_right with fast_dissolve
    sadie "It took us a long time to figure the spell out, but we did it."
    show sadie grin at mid_right with fast_dissolve
    sadie "So you better appreciate it."
    
    tisha smile "I love it.  I'll never forget home with this."
    
    hide rosemarie
    hide sadie
    with dissolve
    
    "I embrace all of my friends in a group hug.  I don't want this moment to end."
    "And yet, summer can't go on forever."
    
    show katya annoyed with dissolve
    katya "Enough sad stuff!"
    show katya big_smile with fast_dissolve
    katya "Let's party!"
    "Katya announces and lets of a party cracker of confetti over our heads."
    
    
    hide katya with dissolve
    
    scene bg black with dissolve
    pause (0.3)
    scene bg inn lobby night with dissolve
    
    show elise uncertain at mid_left with fast_dissolve
    elise "I wish there was something more we could do for them...."
    "Elise muses as we haul all the party supplies back downstairs."
    
    show mika serious at mid_right with fast_dissolve
    mika "Who?"
    
    show elise serious at mid_left with fast_dissolve
    elise "The spirits."
    "She nods toward the glass door leading out to the coutyard at the back of the inn."
    "Three green-gold lights dance among the overgrown grasses outside."
    show elise uncertain at mid_left with fast_dissolve
    elise "Those men will come back.  If not them, then someone else.  Someone will buy this hotel eventually."
    
    hide mika with dissolve
    
    show katya smile at mid_right with dissolve
    katya "Hey, don't worry.  Maybe they'll trap those men in the house too."
    
    show elise startled at mid_left with fast_dissolve
    elise "Katya!  We're witches!  We're supposed to help people and that includes spirits who dwell in abandoned inns!"
    
    show rosemarie awkward with dissolve
    rosemarie "I know something we can do.  And we can do it because we're witches!"
    
    hide rosemarie
    hide elise
    hide katya
    with dissolve
    
    scene bg black with dissolve
    pause (0.3)
    scene bg sky night with nice_wipeup
    pause (0.3)
    scene bg inn courtyard night with dissolve
    
    "The six of us stand in a circle."
    "My friends--"
    show katya smile with dissolve
    pause (0.3)
    hide katya with dissolve
    pause (0.3)
    show sadie smile with dissolve
    pause (0.3)
    hide sadie with dissolve
    pause (0.3)
    show mika frown with dissolve
    pause (0.3)
    hide mika with dissolve
    pause (0.3)
    show elise smile with dissolve
    pause (0.3)
    hide elise with dissolve
    pause (0.3)
    show rosemarie smile with dissolve
    pause (0.3)
    hide rosemarie with dissolve
    "--each of us contribute one part of spell."
    
    "The three spirits hover around the edges of courtyard, curious but afraid to approach."
    "For a moment, the world pauses as the magic takes effect--"
    scene bg inn courtyard night with flash
    extend "--then the courtyard erupts into a field of pale white flowers that bend with the wind from the ocean."
    
    "These are the things I will never forget."
    "The sea, the island, and my friends."
    
    show katya big_smile at mid_left with dissolve
    katya "Last one out to the cars is a rotten egg!"
    hide katya with nice_wipeleft
    
    show sadie annoyed at mid_right with dissolve
    sadie "Hey, wait for me!"
    hide sadie with nice_wipeleft
    
    show mika frown at mid_right with dissolve
    mika "I guess that leaves us to finish carrying out the party supplies."
    
    show rosemarie awkward_smile at mid_left with dissolve
    rosemarie "Oh, I'll help.  I'll come with you, Mika."
    
    hide mika
    hide rosemarie
    with dissolve
    
    show elise uncertain with dissolve
    elise "Are you ready to go, Tish?"
    
    tisha smile "I'm ready."
    
    hide elise with dissolve
    
    scene bg black with dissolve
    pause (0.3)
    scene bg sky night with dissolve
    
    "The End"
    "Story, character art, script cloverfirefly\nBackgrounds Robin Kaplan\nPlease check the about page for links"
    "Thank you for reading!"
    
    
    