:: Get system info
@echo off

REM SET CPATH=%~dp0
SET CPATH=%APPDATA%\とるてそふと\コイ×ミツ　〜八重練紗祈と赤い糸の王子様〜

title 診断情報の収集中……このままお待ちください
echo 診断情報を収集しております。
echo このままお待ちください。
echo;

IF NOT "%CPATH:~-1%"=="\" SET CPATH=%CPATH%\

set YYYYMMDD=%DATE:~0,4%%DATE:~5,2%%DATE:~8,2%
set HHMMSS=%time:~0,2%%time:~3,2%%time:~6,2%
set HHMMSS=%HHMMSS: =0%

set LOGFNAME="%CPATH%infomation.txt"
set DIAGTMP="%CPATH%diagtmp_%computername%_%YYYYMMDD%_%HHMMSS%.txt"

title このままお待ちください……診断情報の収集中（dxdiag）
dxdiag /t %DIAGTMP%

:LOOPLOOP
IF EXIST %DIAGTMP% GOTO :OKOKOKOK
ping localhost>nul
GOTO :LOOPLOOP

:OKOKOKOK
echo %CPATH%%computername%_%YYYYMMDD%_%HHMMSS%>%LOGFNAME%

title このままお待ちください……診断情報の収集中（systeminfo）
systeminfo>>%LOGFNAME%
type %DIAGTMP%>>%LOGFNAME%

title このままお待ちください……診断情報の収集中（ipconfig）
ipconfig /all>>%LOGFNAME%

title このままお待ちください……診断情報の収集中（route print）
route print>>%LOGFNAME%

title このままお待ちください……診断情報の収集中（tasklist）
tasklist /V /FO CSV>>%LOGFNAME%

title このままお待ちください……診断情報の収集中（wmic PROCESS GET）
wmic PROCESS GET /FORMAT:CSV>%LOGFNAME%_processlist.txt

del %DIAGTMP%

title 診断情報の収集中が完了しました

echo >"%CPATH%\このフォルダの中身を全てzipにまとめ、サポートへ送信してください.txt"

cls
echo 診断情報の収集が完了しました。
echo 自動的に開いたフォルダ内のファイル（dat,txt,png等）全てを
echo zipにまとめてサポートへご送付ください。
echo;
echo infomation.txt, infomation.txt_processlist.txt
echo;

start "" explorer "%CPATH%"

echo こちらのウインドウは何かキーを押すと閉じます。
pause > nul

